Макросы для мага
/cast [nopet] Summon Water elemental
/stopmacro [nopet]
/petpassive
/click PetActionButton5
/petattack
Вызывает элема, выбирает нову и приказывает атаковать выбранную цель.
/cancelaura Ice Block
/stopcasting
/cast Ice Block
Прерывает каст и кастует блок, вторым нажатием снимает.
/stopcasting
/cast Counterspell
Прерывает каст и кастует контрспел на выбранную цель.
/stand
/castsequence [button:1,target=player] reset=60 Dampen Magic, Arcane Intellect, ice Armor; [button:2,target=target] reset=10 amplify magic, arcane intellect; [button:2,modifier:shift] reset=10 dampen magic, arcane intellect;
Все бафы одной кнопкой.
Жмем левой мышкой раз - демпен меджик, два - интеллект, три - айс армор. Замените Ice Armor на mage armor или molten armor, смотря что вы предпочитаете. Что интересно, вне зависимости от таргета будет бафать мага.
Правой кнопкой раз - амплифи меджик, два - интеллект. Хочу заметить, что время сброса таймера (reset=60) 60 сек. Т.е. если вы бафнули себя демпен, потом через 2 минуты решили бафнуть себе интеллект, повесится демпен, ибо таймер прошел. Бафает таргет. Интересно, что иконка макро будет меняться, если на следующий спел в очереди не хватает маны. Т.е. после демпена еси на инт не фатаит, но на остальные - да, картинка будет как "нефатаит маны".
------------------------------------------------------------------------------
#showtooltip frostbolt
/stand
/cast frostbolt
Замените frostbolt на pyroblast или fireball, в зависимости от билда. Т.к. умный маг пьет перед тем как убить моба, а не после (а у меня еще и кнопка "встать" на F6 стоит 
), то часто приходится вставать. Уменьшает количество ненужных нажатий. Поставьте картинку спелла и вы не отличите от обычного фростболта кнопку. При наведении на макрос пишет "фростболт, ранк 10, бьет стока-то блаблабла"
------------------------------------------------------------------------------
/stand
/script SpellStopCasting()
/cast Counterspell
Код:
/cast [harm] Arcane Power
/stopcasting [harm]
/cast [harm] Presence of Mind
/stopcasting [harm]
/cast [harm] Pyroblast
-----------------------------------------------------------------------------
#Showtooltip mana emerald;
/cast [button:2] conjure mana emerald;
/use [button:1] mana emerald;
Замените этим макросом ваш гем. Он будет функционировать точно так же , только в придачу можно будет еще правой кнопкой мышки его делать. Кулдаун и наличие (единичка внизу кнопки, или нолик) будет отображаться.
------------------------------------------------------------------------------
#showtooltip Conjured Mountain Spring Water;
/cast [button:1,modifier:shift]Conjure Water;[button:2,modifier:shift]Conjure Food;
/use [button:1,nomodifier]Conjured Mountain Spring Water;[button:2,nomodifier]Conjured Cinnamon Roll;
Это макрос на еду/бухло. Левый клик (или нажатие соотв. кнопки клавы, что одно и то же) - выпить воду (у меня Conjured Mountain Spring Water, посему в макро именно эта вода), правый - схавать булку. Shift+левый_клик - сделать воду, Shift+правый_клик - сделать булок. Оффтоп: в WotLK магам обещали спелл, создающий стол с хавчиком для пати мемберов. Заюзал - садишься пить+есть, по аналогии с пристовским колодцем. Встречайте скатерть-самобранку xD
#showtooltip Arcane Explosion
/cast [nocombat] Arcane Explosion(Rank 1); Arcane Explosion
Объяснение:
Кастует аркан экспложен первого ранга не в комбате, и аркан экспложен максимального в комбате.
/stopcasting
/cast Counterspell
Объяснение:
Интерапт каста и кс. тут все понятно.
Объяснение:
/cast [nopet] Summon Water Elemental
/petpassive
Саммонит элема и переводит его в пассивный режим. Важно на арене, чтобы элем не бил например по заовцованому вару. (по дефолту элем бьет того кто тебя атакует)
/cast Icy Veins
/use Scryer's Bloodgem
/use Vengeance of the Illidari
/cast Frostbolt
Объяснение:
Фростбол удобренный венусом и тринками
/cast Icy Veins
/cast Frostbolt(Rank 1)
Объяснение:
Фростобол первого ранга с венусом (полезно для кайта варов и друлей)
#show Ice Barrier
/cast [modifier:shift] Fire Ward
/cast [modifier:ctrl] Frost Ward
/cast Ice Barrier
Объяснение:
Клевый макрос - по умолчанию айс барьер, с шифтом фаервард, с контролом фрост вард. 3 в 1.
/use Vengeance of the Illidari
/use Scryer's Bloodgem
/cast Ice Lance
Объяснение:
Удобренный ланс.
/cast Frost Nova
/click [pet] PetActionButton5
Объяснение:
Кастует либо нову, либо нову элема если проста на откате.
#show Polymorph
/clearfocus [modifier:shift]
/focus [target=focus,noexists]; [target=focus,dead]
/clearfocus [target=focus,help]
/stopcasting
/cast [target=focus,exists,harm] Polymorph; Polymorph
Объяснение:
Макрос на фокус овцу.
Работаеь так . вначале с помощью простого макроса /focus выбираем цель фокуса. потом этим макро можем шипать не отрываясь от нюкаемой цели.
допустим мы против вар+пал. ставим фокус на вара. нюкаем пала. и не снимая таргета с пала шипаем вара.